***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*June 05, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt RB520S30 A K 
.param
+vc0 = 2.146e-9	        vc1 = 9.316e-9		vc2 = 1.000		vc3 = 4.313e-9		vc4 = 1.265e-1
+tc1 = 8.058e-2		tc2 = 4.926e-2		tc3 = 2.858e-2	        tc4 = 4.886e-2
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1        
***** dc model parameter *****
+ is = 7.851e-8	  	  n = 1.011		 rs = 5.750e-1		ikf = 1.162e-1  
+ibv = 5e-3		nbv = 1		         bv = 33               
***** capacitance parameter *****
+cjo = 2.451e-10	  m = 4.780e-1	         vj = 5.502e-1 
+ fc = 0.5 
***** temperature coefficient *****
+tnom = 25		 eg = 0.632	       xti  = 3
+trs1 = -7.996e-6      trs2 = 4.509e-8	       tikf = -6.566e-3
.ends RB520S30
*$
